Versions: 95 +

So you've got a networked database and you need an easy way of deploying customised desktop shortcuts for it to your users. Here's a cunning method.

The basis for this method is the use of Visual Basic scripting in the form of a VBS file - saves you having to build a setup.exe file or anything strenuous like that. Now VBS files have had something of a bad press, mainly because script-kiddies have used them to write viruses. Don't let that put you off.

1. Prompts the user to confirm their database username - since I use the user's NT username for their database username, this is shown as the default response. If you're not using user-level security you can skip this step.
2. Creates and names the shortcut, checking the Registry to look-up the location of the user's version of Access (you can hard-code the Access executable's location if you'd prefer)
3. Sets the "run in" directory
4. Sets the shortcut icon
5. Sets the shortcut's window style

• MyApp is the name of the database application
• \\myserver\myshare\myfolder\myapp.mdb is the location of the database file
• \\myserver\myshare\myfolder\system.mdw is the location of the workgroup information file
• \\myserver\myshare\myfolder\myapp.ico is the location of the application icon file

'Code sample from Accessory http://www22.brinkster.com/accessory
Set WshNetwork = WScript.CreateObject("WScript.Network")
Dim strI
strI = InputBox("Enter your MyApp database username here. If a default has been suggested, please check it before you proceed, " & _
    "amending as required." & Chr(10) & Chr(13) & Chr(10) & Chr(13) & "NOTE: leaving this blank cancels the installation!", _
    "MyApp shortcut personalisation", WshNetwork.Username)
If Len(strI)>0 Then
    Dim WSHShell
    Set WSHShell = WScript.CreateObject("WScript.Shell")
    Dim MyShortcut, DesktopPath, AccessPath
    DesktopPath = WSHShell.SpecialFolders("Desktop")
    Set MyShortcut = WSHShell.CreateShortcut(DesktopPath & "\MyApp - production.lnk")
    AccessPath = WSHShell.RegRead("HKCR\.mdb\")
    AccessPath = WSHShell.RegRead("HKCR\" & AccessPath & "\shell\new\command\")
    AccessPath = Replace(Left(AccessPath, InStr(1, AccessPath,"/", 1) -1), """", "")
    MyShortcut.TargetPath = AccessPath
    MyShortcut.Arguments = "\\myserver\myshare\myfolder\myapp.mdb /wrkgrp \\myserver\myshare\myfolder\system.mdw /user " & strI
    MyShortcut.WorkingDirectory = "C:\Program Files\Microsoft Office\Office\"
    MyShortcut.WindowStyle = 3 '1=normal, 2=minimised, 3=maximised
    MyShortcut.IconLocation = "\\myserver\myshare\myfolder\myapp.ico" 
    MyShortcut.Save
    Msgbox "Installation completed successfully.", 64, "MyApp"
Else
    Msgbox "Installation was cancelled.", 48, "MyApp"
End If